home *** CD-ROM | disk | FTP | other *** search
/ Gekikoh Dennoh Club 2 / Gekikoh Dennoh Club Vol. 2 (Japan).7z / Gekikoh Dennoh Club Vol. 2 (Japan) (Track 01).bin / fsw / zm302 / zm302_s.lzh / MPSRC045.LZH / P8_0102.HAS < prev    next >
Text File  |  1996-06-16  |  2KB  |  88 lines
  1. *=======================================================
  2. *
  3. *    ８ｂｉｔＰＣＭ 7.8kHz変換
  4. *
  5. *=======================================================
  6.  
  7. PCM8_0102_mac    macro        _vol
  8.  
  9.         moveq.l        #MIX_SIZE-1,d6        * 48 * 2 = 96 <= 127 で moveq OK
  10.         add.l        a0,d6
  11.         cmp.l        a3,d6
  12.         bcs        @f            * 今回の処理中にはトラップしない
  13.  
  14.         * トラップ判定付きの変換
  15.         moveq.l        #MIX_SIZE-1-1,d6
  16. 2:        cmpa.l        a3,a0            * トラップアドレス判定
  17.         bcs        1f
  18.         jsr        (a4)            * トラップ!
  19. 1:        move.b        (a0)+,d0        * PCMデータ取り込み
  20.         ext.w        d0            * 符号拡張
  21.         VOLUME        _vol,d0,d2
  22.         add.w        d0,(a1)+
  23.         add.w        d0,(a1)+
  24.         dbra        d6,2b
  25.  
  26. *        ラストの１回
  27.         cmpa.l        a3,a0
  28.         bcs        1f
  29.         jsr        (a4)            * トラップ!
  30. 1:        move.b        (a0)+,d0        * PCMデータ取り込み
  31.         ext.w        d0            * 符号拡張
  32.         move.w        d0,CH_LAST_PCM(a5)    * 前回変換終了時のPCM値 = d0.w
  33.         VOLUME        _vol,d0,d2
  34.         move.w        d0,CH_LAST_VPCM(a5)    * 最後のPCM値(音量変換後)
  35.         add.w        d0,(a1)+
  36.         add.w        d0,(a1)+
  37.  
  38.         move.l        a0,CH_PCM_ADR(a5)    * PCMアドレス = a0.l
  39.  
  40.         rts
  41.  
  42.  
  43.         * トラップ無しの変換
  44.  
  45. @@:        moveq.l        #MIX_SIZE-1-1,d6
  46. 2:        move.b        (a0)+,d0        * PCMデータ取り込み
  47.         ext.w        d0            * 符号拡張
  48.         VOLUME        _vol,d0,d2
  49.         add.w        d0,(a1)+
  50.         add.w        d0,(a1)+
  51.         dbra        d6,2b
  52.  
  53. *        ラストの１回
  54.         move.b        (a0)+,d0        * PCMデータ取り込み
  55.         ext.w        d0            * 符号拡張
  56.         move.w        d0,CH_LAST_PCM(a5)    * 前回変換終了時のPCM値 = d0.w
  57.         VOLUME        _vol,d0,d2
  58.         move.w        d0,CH_LAST_VPCM(a5)    * 最後のPCM値(音量変換後)
  59.         add.w        d0,(a1)+
  60.         add.w        d0,(a1)+
  61.  
  62.         move.l        a0,CH_PCM_ADR(a5)    * PCMアドレス = a0.l
  63.  
  64.         rts
  65.   
  66.         endm
  67.  
  68. *=======================================================
  69.  
  70. PCM8_0102_v00:    PCM8_0102_mac    0
  71. PCM8_0102_v01:    PCM8_0102_mac    1
  72. PCM8_0102_v02:    PCM8_0102_mac    2
  73. PCM8_0102_v03:    PCM8_0102_mac    3
  74. PCM8_0102_v04:    PCM8_0102_mac    4
  75. PCM8_0102_v05:    PCM8_0102_mac    5
  76. PCM8_0102_v06:    PCM8_0102_mac    6
  77. PCM8_0102_v07:    PCM8_0102_mac    7
  78. PCM8_0102_v08:    PCM8_0102_mac    8
  79. PCM8_0102_v09:    PCM8_0102_mac    9
  80. PCM8_0102_v10:    PCM8_0102_mac    10
  81. PCM8_0102_v11:    PCM8_0102_mac    11
  82. PCM8_0102_v12:    PCM8_0102_mac    12
  83. PCM8_0102_v13:    PCM8_0102_mac    13
  84. PCM8_0102_v14:    PCM8_0102_mac    14
  85. PCM8_0102_v15:    PCM8_0102_mac    15
  86. PCM8_0102_vnn:    PCM8_0102_mac    'n'
  87. PCM8_0102_non:    PCM8_0102_mac    'x'
  88.